early morning musing (in Lisp)

[hyuri]

y’know, it’s really too bad I can’t set Windows up with something like this:

(defun my-colors-light (&optional frame)
  "Set colors suitable for working in light environment,
i.e. in daylight or under bright electric lamps."
  (interactive)
  (if frame
      (select-frame frame)
    (setq frame (selected-frame)))
  ;; Color with minimal eye fatigue in light environments
  ;; is "AntiqueWhite3" (RGB: 205 182 176),
  (set-background-color "AntiqueWhite3")
  (set-foreground-color "black")
  (set-cursor-color "DarkSlateGrey")
  (when (facep 'region)
    (set-face-background 'region "DarkGrey" frame))
  (when (facep 'fringe)
    (set-face-background 'fringe (face-background 'default) frame)
    (set-face-foreground 'fringe (face-foreground 'default) frame)))

(define-key global-map [f6 ?c ?s] 'my-colors-light)

(defun my-colors-dark (&optional frame)
  "Set colors suitable for working in the darkness without electricity."
  (interactive)
  (if frame
      (select-frame frame)
    (setq frame (selected-frame)))
  (set-background-color "black")
  (set-foreground-color "DarkGrey")
  (set-cursor-color "DarkSlateGrey")
  (when (facep 'region)
    (set-face-background 'region "DimGrey" frame))
  (when (facep 'fringe)
    (set-face-background 'fringe (face-background 'default) frame)
    (set-face-foreground 'fringe (face-foreground 'default) frame)))

(define-key global-map [f6 ?c ?d] 'my-colors-dark)

;; Automatically switch to dark background after sunset
;; and to light background after sunrise.
;; (Not that 'calendar-latitude' and 'calendar-longitude'
;;  should be set before calling the 'solar-sunrise-sunset')
(defun my-colors-set (&optional frame)
  (interactive)
  (require 'solar)
  (if (and calendar-latitude calendar-longitude calendar-time-zone)
     (let* ((l (solar-sunrise-sunset (calendar-current-date)))
            (sunrise-string (apply 'solar-time-string (car l)))
	    (sunset-string (apply 'solar-time-string (car (cdr l))))
	    (current-time-string (format-time-string "%H:%M")))
       (if (or (string-lessp current-time-string sunrise-string)
	       (string-lessp sunset-string current-time-string))
	   (my-colors-dark frame))
       (if (and (boundp 'my-sunset-timer)  (timerp my-sunset-timer))
	   (cancel-timer my-sunset-timer))
       (if (and (boundp 'my-sunrise-timer) (timerp my-sunrise-timer))
	   (cancel-timer my-sunrise-timer))
       (setq my-sunset-timer  (run-at-time sunset-string  (* 60 60 24) 'my-colors-dark))
       (setq my-sunrise-timer (run-at-time sunrise-string (* 60 60 24) 'my-colors-light)))))

(my-colors-set)
(add-to-list 'after-make-frame-functions 'my-colors-set)

Comments

[djinubito.livejournal.com]

Interesting.

[hyuri.livejournal.com]

Do I detect a hint of sarcasm?

[djinubito.livejournal.com]

Nope. =)

[science-vixen.livejournal.com]

nifty.

I presume that this does work in other OSes like linux?

[hyuri.livejournal.com]

Actually, that’s just in my .emacs (http://hyuri.org/other/.emacs). So I guess in a way it does work in Windows...

ANEURISM!!!

[drgnmstralex.livejournal.com]

*goes blind*

....wtf was that? #_#

Re: ANEURISM!!!

[hyuri.livejournal.com]

That, my friend, is Emacs-Lisp. A vile yet somehow nifty little language. ^_^

Re: ANEURISM!!!

[jedifreeman.livejournal.com]

and I must add that it is much more read-able than true Lisp, which is a wierd-freaky language (although very useful for different things). :-P

[kelston.livejournal.com]

Man, that would cost me like 2 fps in games. I can't handle that!

[hyuri.livejournal.com]

Eh, what’s a couple of frames? You only need 30!

[kelston.livejournal.com]

I blame John Carmack for making an engine that requires things like exactly 120 frames to do a specific rocket jump in Quake 3 and other things. Dang! You should teach him, har har.